JXL
18th February 2003 23:44 UTC

checking version
Hello all,

I made a version check on installer startup.
It works as well, but i have a problem with the check in combination with Language selection.

That's my code:
Function .onInit
ReadRegStr $1 HKCU "Software\myapp" "Version"
StrCmp $1 "${MUI_VERSION}" 0 Abort
MessageBox MB_OK "You have the latest Version installed."
Abort:

;Language selection

;Font
Push Tahoma
Push 8

;Languages
!insertmacro MUI_LANGDLL_PUSH "English"
!insertmacro MUI_LANGDLL_PUSH "French"
!insertmacro MUI_LANGDLL_PUSH "German"
!insertmacro MUI_LANGDLL_PUSH "Spanish"
...
...
FunctionEnd

So when the installer starts up it shows me that i have already the latest version but when i click on OK the language selection window opens.

The installer should quit after the Abort.

Anyone who can help me ?

iceman_k
19th February 2003 03:26 UTC

The Abort you have in your code is a label, not a command.
Do this:

Function .onInit
ReadRegStr $1 HKCU "Software\myapp" "Version"
StrCmp $1 "${MUI_VERSION}" 0 continue
MessageBox MB_OK "You have the latest Version installed."
Abort
continue:

;Language selection

;Font
Push Tahoma
Push 8

;Languages
!insertmacro MUI_LANGDLL_PUSH "English"
!insertmacro MUI_LANGDLL_PUSH "French"
!insertmacro MUI_LANGDLL_PUSH "German"
!insertmacro MUI_LANGDLL_PUSH "Spanish"
...
...
FunctionEnd

iceman_k
19th February 2003 03:29 UTC

Another problem with your installer: If someone has the latest version installed and then runs an older installer, it will blow away the latest version and install an older version.
You need better version checking.
See Sunjammer's Dotted Comparison Script in the NSIS archive.

Smile2Me
19th February 2003 07:37 UTC

The script can be found here:
http://nsis.sourceforge.net/archive/...instances=0,11

BTW, I wrote it, not Sunjammer, but NP :)

-Hendri.

Sunjammer
19th February 2003 09:10 UTC

bad iceman_k :)

Smile2Me
19th February 2003 09:12 UTC

LOL @ Sunjammer :D

iceman_k
19th February 2003 15:00 UTC

My bad. I should read the attributions more carefully.

Smile2Me
19th February 2003 17:38 UTC

Yep, but it's OK already. No big deal :)

What matters is that I hope that JXL and more people can use the script for their installer :)

Have fun, greetz,
-Hendri.

JXL
19th February 2003 20:18 UTC

Many thanks, it works with your script.

All i need now is something to abort the installation when the check calls $0 or $1 and continue the installation on $2. It should have something like the continue tag to show the language window when $2 is called.

Smile2Me
19th February 2003 20:37 UTC

If I understand your question correctly: StrCmp the output of the script with '2'. If '2' then continue (go to some label). In the other case, continue and the installer will come across the abort and abort the installer. Just as iceman_k explained in the reply above.

Does that answer it?

-Hendri.

JXL
19th February 2003 21:09 UTC

Could your show me a example ?

Smile2Me
19th February 2003 21:19 UTC

Push ${version number saved in registry}
Push ${version of software in installer}
Call VersionCheck
Pop $0
StrCmp $0 '2' Continue
Abort 'A newer or the same version of this software is already installed'

Continue:
...

JXL
21st February 2003 08:54 UTC

This doesn't work for me.
I've added this:

Call VersionCheck
Pop $0
StrCmp $0 "2" continue 0
MessageBox MB_OK "You are updating from ($1) to (${MUI_VERSION})"
Abort

StrCmp $0 "0" 0 continue
MessageBox MB_OK "You have the latest MVersion installed."
Abort

StrCmp $0 "1" 0 continue
MessageBox MB_OK "You have already a newer version installed ($1). This is (${MUI_VERSION})"
Abort
continue:

What's wrong ?

Smile2Me
21st February 2003 08:59 UTC

Take a look at the labels. It will never visit the code where it compares the output of VersionCheck with '0' nor the part to compare with '1'. Add some additional labels:

Call VersionCheck 
Pop $0 
StrCmp $0 "2" 0 continue1
MessageBox MB_OK "You are updating from ($1) to (${MUI_VERSION})" 
Goto continue 

continue1:
StrCmp $0 "0" 0 continue2 
MessageBox MB_OK "You have the latest MVersion installed." 
Abort 

continue2:
; [not necessary anymore] StrCmp $0 "1" 0 continue 
MessageBox MB_OK "You have already a newer version installed ($1). This is (${MUI_VERSION})" 
Abort

continue: 

JXL
21st February 2003 09:07 UTC

Great, it works.
Sorry, i suck at scripting. It's my first project with NSIS.
Well, it's a great installer with many options but you have to read the whole docu to understand how the variables are working. And i couldn't find these continue or Abort labels to look at them how they works.

And big thx for your help.

Smile2Me
21st February 2003 09:11 UTC

NP, that's what we're here for :)

To clarify: the continue labels are custom labels, you can give them any name you want. As long as they end with ':' it is a custom label. Abort however is a function, not a label.

One more thing: the last StrCmp is not necessary anymore: if it is not a 2 nor a zero then it has to be a 1. So that one line can be deleted from the script...

Good luck scripting, greetz,
-Hendri.

Yovav
13th May 2003 03:40 UTC

warning
Quote:

install function "VersionCheck" not referenced - zeroing code (15-62) out

Function VersionCheck
  Exch $0 ;second versionnumber
  Exch
  Exch $1 ;first versionnumber
  Push $R0 ;counter for $0
  Push $R1 ;counter for $1
  Push $3 ;temp char
  Push $4 ;temp string for $0
  Push $5 ;temp string for $1
  StrCpy $R0 "-1"
  StrCpy $R1 "-1"
  Start:
  StrCpy $4 ""
  DotLoop0:
  IntOp $R0 $R0 + 1
  StrCpy $3 $0 1 $R0
  StrCmp $3 "" DotFound0
  StrCmp $3 "." DotFound0
  StrCpy $4 $4$3
  Goto DotLoop0
  DotFound0:
  StrCpy $5 ""
  DotLoop1:
  IntOp $R1 $R1 + 1
  StrCpy $3 $1 1 $R1
  StrCmp $3 "" DotFound1
  StrCmp $3 "." DotFound1
  StrCpy $5 $5$3
  Goto DotLoop1
  DotFound1:
  Strcmp $4 "" 0 Not4
    StrCmp $5 "" Equal
    Goto Ver2Less
  Not4:
  StrCmp $5 "" Ver2More
  IntCmp $4 $5 Start Ver2Less Ver2More
  Equal:
  StrCpy $0 "0"
  Goto Finish
  Ver2Less:
  StrCpy $0 "1"
  Goto Finish
  Ver2More:
  StrCpy $0 "2"
  Finish:
  Pop $5
  Pop $4
  Pop $3
  Pop $R1
  Pop $R0
  Pop $1
  Exch $0
FunctionEnd

Call VersionCheck

Call VersionCheck