MarkDecaf
22nd May 2006 16:01 UTC

Changing the Default Text in MUI Template
I am trying to change the Default Text in the License Template of the MUI. I have tried and I just can't change it without changing the language file too. Here's my code:

; Load up the Individual Wizard Screens
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "..\$(AppName)_${APPVERSION}\readme.txt"
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

; Load up the Uninstall Wizard Screens
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

; Set languages (first is default language)
!insertmacro MUI_LANGUAGE "English"
!insertmacro MUI_RESERVEFILE_LANGDLL

; Change the Defult License Agreement to Look like a Readme Dialog
!define MUI_TEXT_LICENSE_TITLE "Readme File"
!define MUI_TEXT_LICENSE_SUBTITLE "Please review the readme file before installing $(^NameDA)."
!define MUI_INNERTEXT_LICENSE_TOP "Press Page Down to see the rest of the readme file."
!define MUI_INNERTEXT_LICENSE_BOTTOM "When you have finished reading, click on Next to start installing."

When I compile with this code it ignores the changes and sticks in the default code. When I place the !insertmacro MUI_LANGUAGE "English" after the updated !define statements then I get a notice that the variable is already defined.

I have tried placing the block in different positions and can't get it to work. Is there a bug or is it my code? I can change it in the Language file, but that's cheating and if I share the source for my installer then I have to make a note to change the language file too.

Red Wine
22nd May 2006 16:42 UTC

According on Joost's (MUI developer) post on other thread:

; Load up the Individual Wizard Screens
!insertmacro MUI_PAGE_WELCOME
###############################
; Change the Defult License Agreement to Look like a Readme Dialog
!define MUI_PAGE_HEADER_TEXT "Readme File"
!define MUI_PAGE_HEADER_SUBTEXT "Please review the readme file before installing $(^NameDA)."
!define MUI_LICENSEPAGE_TEXT_TOP "Press Page Down to see the rest of the readme file."
!define MUI_LICENSEPAGE_TEXT_BOTTOM "When you have finished reading, click on Next to start installing."
###############################
!insertmacro MUI_PAGE_LICENSE "..\$(AppName)_${APPVERSION}\readme.txt"
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

; Load up the Uninstall Wizard Screens
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

; Set languages (first is default language)
!insertmacro MUI_LANGUAGE "English"
!insertmacro MUI_RESERVEFILE_LANGDLL

Red Wine
22nd May 2006 17:12 UTC

The above post edited to correct state :-)
You may also use more defines for License page.
Refer to MUI Readme.
e.g.
MUI_LICENSEPAGE_BUTTON button_text
MUI_LICENSEPAGE_CHECKBOX
MUI_LICENSEPAGE_CHECKBOX_TEXT text
MUI_LICENSEPAGE_RADIOBUTTONS
MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_ACCEPT text
MUI_LICENSEPAGE_RADIOBUTTONS_TEXT_DECLINE text