Archive: Large Title
Large Title
Hi
In another post I learn about this tip
!define MUI_WELCOMEPAGE_TITLE_3LINES
!define MUI_FINISHPAGE_TITLE_3LINES
It is used to show a large title in the welcome and finish page.
But when I put
!define MUI_UNWELCOMEPAGE_TITLE_3LINES
!define MUI_UNFINISHPAGE_TITLE_3LINES
It doesnt work in the Unisntaller.
Why?
Thanks in advance
Hi boyo!
There is a note in the Modern UI Readme.
"Note: There is no difference between installer and uninstaller page settings."
http://nsis.sourceforge.net/Docs/Mod...UI/Readme.html
Page settings
Cheers
Bruno
OK Bruno, but still doesnt work if I only write
!define MUI_WELCOMEPAGE_TITLE_3LINES
!define MUI_FINISHPAGE_TITLE_3LINES
And nothing for Unistaller
Whats wrong??
Hi Boyo!
Did you introduce these defines before the
!insertmacro MUI_PAGE_WELCOME
command?
Cheers
Bruno
This is a part of my code, did you see something wrong?
;--------------------------------
;Interface Configuration
!define MUI_ABORTWARNING
!define MUI_COMPONENTSPAGE_SMALLDESC
!define MUI_ICON "iSG.ico"
!define MUI_UNICON "iSG.ico"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "Header.bmp"
!define MUI_HEADERIMAGE_BITMAP_NOSTRECH
!define MUI_WELCOMEPAGE_TITLE_3LINES
!define MUI_WELCOMEFINISHPAGE_BITMAP "Right.bmp"
!define MUI_WELCOMEFINISHPAGE_BITMAP_NOSTRECH
!define MUI_LICENSEPAGE_RADIOBUTTONS
!define MUI_UNWELCOMEFINISHPAGE_BITMAP "Right.bmp"
!define MUI_UNWELCOMEFINISHPAGE_BITMAP_NOSTRECH
!define MUI_FINISHPAGE_TITLE_3LINES
!define MUI_FINISHPAGE_SHOWREADME $(MUIReadMe)
!define MUI_FINISHPAGE_LINK "http://www.url.com"
!define MUI_FINISHPAGE_LINK_LOCATION "http://www.url.com"
!define MUI_FINISHPAGE_NOAUTOCLOSE
!define MUI_UNWELCOMEPAGE_TITLE_3LINES
!define MUI_UNFINISHPAGE_TITLE_3LINES
!define MUI_UNFINISHPAGE_NOAUTOCLOSE
;--------------------------------
;Pages
; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE $(MUILicense)
; Components page
!insertmacro MUI_PAGE_COMPONENTS
; Directory page
!define MUI_PAGE_CUSTOMFUNCTION_PRE dir_pre
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!insertmacro MUI_PAGE_FINISH
; Uninstaller pages
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH
;--------------------------------
Hi Boyo!
Everything ok.
Can you spot a difference if you comment the line
!define MUI_WELCOMEPAGE_TITLE_3LINES
Cheers
Bruno
Bruno
If I comment the line you say, the installer looks fine, but the Uninstaller still with problem.
Any idea?
Use the same before the uninstaller pages as well.
HI kichik
I dont understand you, please be more explicit
Thanks
You should read the MUI documentation carefully. Your script does not meet the MUI requirements.
The following piece of info copied from MUI documentation:
Page settings apply to a single page and should be set before inserting a page macro.
You have to repeat the setting if you want it to apply to multiple pages.
Example:
;Add a directory page to let the user specify a plug-ins folder
;Store the folder in $PLUGINS_FOLDER
Var PLUGINS_FOLDER
!define MUI_DIRECTORYPAGE_VARIABLE $PLUGINS_FOLDER
!insertmacro MUI_PAGE_DIRECTORY
Note: There is no difference between installer and uninstaller page settings.
Here is an example of usage:
outfile '3lines.exe'
InstallDir '$PROGRAMFILES\3Lines Test'
!define WELCOME_TITLE 'Welcome to the extra 3 lines test setup wizard. \
This page has extra space for the welcome title!'
!define UNWELCOME_TITLE 'Welcome to the extra 3 lines test uninstall wizard. \
This page has extra space for the UN-welcome title!'
!define FINISH_TITLE 'Finished the extra 3 lines test setup wizard. \
This page has extra space for the finish title!'
!define UNFINISH_TITLE 'Finished the extra 3 lines test uninstall wizard. \
This page has extra space for the UN-finish title!'
!Include 'MUI.nsh'
!define MUI_WELCOMEPAGE_TITLE '${WELCOME_TITLE}'
!define MUI_WELCOMEPAGE_TITLE_3LINES
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!define MUI_FINISHPAGE_TITLE '${FINISH_TITLE}'
!define MUI_FINISHPAGE_TITLE_3LINES
!insertmacro MUI_PAGE_FINISH
!define MUI_WELCOMEPAGE_TITLE '${UNWELCOME_TITLE}'
!define MUI_WELCOMEPAGE_TITLE_3LINES
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_INSTFILES
!define MUI_FINISHPAGE_TITLE '${UNFINISH_TITLE}'
!define MUI_FINISHPAGE_TITLE_3LINES
!insertmacro MUI_UNPAGE_FINISH
!insertmacro MUI_LANGUAGE "English"
Section -
SetOutPath '$INSTDIR'
WriteUninstaller 'uninstall.exe'
SectionEnd
Section Uninstall
Delete '$INSTDIR\uninstall.exe'
RmDir '$INSTDIR'
SectionEnd
Again
Thanks a lot RW