kukomamasan
4th October 2008 12:41 UTC

Link Websites at the end of installation.
Hi all,
I wonder how you can add at the finish page of the installer, to show a window of links to urls with descriptions that users meight wanna goto?
i know

Function .onInstSuccess
Messagebox MB_YESNO "Wanna visit Website?" IDYES +2
abort
ExecShell "open" "http://www.somesite.com"
Functionend

will give the option to open 1 link, but if i want to have like 5 link shown on an page ? that users meight wanna visit, how is that done?

Animaether
4th October 2008 22:17 UTC

create a custom page and present the links on that page; either InstallOptions or the new nsdialogs will do the trick.. look into those :)

Yathosho
5th October 2008 10:30 UTC

you can use

!define MUI_FINISHPAGE_LINK "My webpage"
!define MUI_FINISHPAGE_LINK_LOCATION "http://bla.com"

!define MUI_FINISHPAGE_SHOWREADME
!define MUI_FINISHPAGE_SHOWREADME_TEXT "My webpage"
!define MUI_FINISHPAGE_SHOWREADME_FUNCTION CallWebpageFunction

Animaether
5th October 2008 15:30 UTC

Yathosho - those only allow one single link, however; if you want multiple links, base MUI defines and macros won't do

kukomamasan
5th October 2008 18:54 UTC

I tried the new nsdialogs, but it only show me the links, was not able to click on them, and then ie would open them ? , it was just in an ordinary text form, not what i wanted.

i read somewhere in the forum, that placing an url in an text box would automactialy be an clickable url, but not in my case?

ZmAn3
5th October 2008 23:41 UTC

assuming you are using a current version of nsis the following will work

Var Link
Var Link2
Var Link3
;--put vars above before your custom nsdialogs page code


;--In your nsdialogs page where you had the text control put somthing like these-----------------
;--Create first Link ----------------------------------
        ${NSD_CreateLInk} 10 10 213 16 "Visit our website for more info " 
        Pop $LINK
        ${NSD_OnClick} $LINK onClickLink ;<--function to execute when link clicked
;-- End Create Link--------------------------------------------------

;--Create second Link ------------------------------------
        ${NSD_CreateLInk} 10 25 213 16 "Visit our forums for help" 
        Pop $LINK2
        ${NSD_OnClick} $LINK2 onClickLink2
;-- End Create Link------------------------------------------------------

;--Create third Link ------------------------------------
        ${NSD_CreateLInk} 10 40 213 16 "visit our examples page" 
        Pop $LINK3
        ${NSD_OnClick} $LINK3 onClickLink3
;-- End Create Link------------------------------------------------------

;--after your custom nsdialogs page function is ALL done put something like these--------------



Function onClickLink
Pop $0
ExecShell "open" "http://nsis.sourceforge.net/Main_Page"
FunctionEnd

Function onClickLink2
Pop $0
ExecShell "open" "http://forums.winamp.com/forumdisplay.php?s=&forumid=65"
FunctionEnd

Function onClickLink3
Pop $0
ExecShell "open" "http://nsis.sourceforge.net/Category:Code_Examples"
FunctionEnd

kukomamasan
7th October 2008 15:31 UTC

Above Works just like i wanted, thx for the help, and adding descriptions, then a noob like me can figure it out :-).