BarbaraG
23rd March 2009 21:42 UTC

Uninstall Title Issue
I am a bit new to NSIS and have some basic questions. I have defined MUI_WELCOME_TITLE and that works great for the installer part.

But the uninstaller is using the value I have set for NAME as the title of each window. I need to change it but I all I have found so far is the TEXT_TOP for the unConfirm page.

Using code I have found on this forum I have a function that will change the font size for the text below the title. I have no problems using API calls and found the ID of 1037 for this control. Sadly, the text will not change, just the font.

So, I would like to know if there is a simpler way to change the title for the Uninstall.

How do I find the nsDialogs list indicating the control number for the Title?

Thanks for any help,

Barbara

Animaether
23rd March 2009 23:15 UTC

"Use !define MUI_WELCOMEPAGE_TEXT again before !insertmacro MUI_UNPAGE_WELCOME" - Stu
From: http://forums.winamp.com/showthread.php?threadid=224015

BarbaraG
23rd March 2009 23:59 UTC

MUI_WELCOMEPAGE_TEXT does not alter the title of the window, which is what I need to change.

The uninstaller is using the string assigned to NAME. There has to be someway to change this that I have just not found.

BarbaraG
24th March 2009 00:15 UTC

Let me clarify my problem.

It seems that the installer is using the CAPTION, which is great. But the uninstaller is using the NAME.

I want to change the caption for the uninstaller since it is wrong.

Animaether
24th March 2009 00:18 UTC

are you referring to the title of the welcome page...

!include "winmessages.nsh"
!include "LogicLib.nsh"
!include "nsDialogs.nsh"
!include "MUI2.nsh"

Outfile "test.exe"

Name "Test"

!define MUI_WELCOMEPAGE_TITLE "Welcome"
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES

Section "Test"
        WriteUninstaller "$TEMP\uninstaller.exe"
        Exec "$TEMP\uninstaller.exe"
SectionEnd

!define MUI_WELCOMEPAGE_TITLE "UnWelcome"
!insertmacro MUI_UNPAGE_WELCOME

!insertmacro MUI_LANGUAGE "English"

!include "winmessages.nsh"
!include "LogicLib.nsh"
!include "nsDialogs.nsh"
!include "MUI2.nsh"

Outfile "test.exe"

Name "Test"

!define MUI_PAGE_CUSTOMFUNCTION_PRE TitlebarChange
!define MUI_WELCOMEPAGE_TITLE "Welcome"
!insertmacro MUI_PAGE_WELCOME
Function TitlebarChange
        SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Titlebar - Welcome"
FunctionEnd

!insertmacro MUI_PAGE_INSTFILES

Section "Test"
        WriteUninstaller "$TEMP\uninstaller.exe"
        Exec "$TEMP\uninstaller.exe"
SectionEnd

!define MUI_PAGE_CUSTOMFUNCTION_SHOW un.TitlebarChange
!define MUI_WELCOMEPAGE_TITLE "UnWelcome"
!insertmacro MUI_UNPAGE_WELCOME
Function un.TitlebarChange
        SendMessage $HWNDPARENT ${WM_SETTEXT} 0 "STR:Titlebar - UnWelcome"
FunctionEnd

!insertmacro MUI_LANGUAGE "English"

Animaether
24th March 2009 00:20 UTC

ahhhhh... well that's easy enough even without runtime code.
UninstallCaption is your ticket.

Caption "This is a Caption"
UninstallCaption "This is an UninstallCaption"

BarbaraG
24th March 2009 00:59 UTC

Wow, amazing when I have the right commands things really do work. The "UninstallCaption" worked perfectly.

I should be happy with everything I learned during my several hours of trying many stuff that did not work. But right now I just feel very silly.

Thanks to everyone. Great support.