Size Subtitle ' s fonts

hi ,

i have another question... i would change the size of the fonts of the subtitle because it is too small ( on all page )

is it possible ? and if yes how can i make this ?

thx

Everything is in the forum, see this thread for instance:



EXAMPLE:

!define APP_NAME 'Test'



name ${APP_NAME}

outfile '${APP_NAME}.exe'

showinstdetails show

InstallDir '$PROGRAMFILES\${APP_NAME}'



!include 'mui.nsh'



!insertmacro MUI_PAGE_WELCOME



!define MUI_PAGE_CUSTOMFUNCTION_PRE ChangeSubtitleFont

!insertmacro MUI_PAGE_LICENSE '${NSISDIR}\License.txt'



!define MUI_PAGE_CUSTOMFUNCTION_PRE ChangeSubtitleFont

!insertmacro MUI_PAGE_COMPONENTS



!define MUI_PAGE_CUSTOMFUNCTION_PRE ChangeSubtitleFont

!insertmacro MUI_PAGE_DIRECTORY



!define MUI_PAGE_CUSTOMFUNCTION_PRE ChangeSubtitleFont

!insertmacro MUI_PAGE_INSTFILES



!insertmacro MUI_PAGE_FINISH



!insertmacro MUI_LANGUAGE "English"



function ChangeSubtitleFont

GetDlgItem $1 $HWNDPARENT 1038

CreateFont $0 "Tahoma" "9" "500"

SendMessage $1 0x0030 $0 0

functionend



section !Required Section

SectionIn RO

sectionend



Section /o Optional



SectionEnd

EDIT: Concluded that there is no need to call the ChangeSubtitleFont function in every page pre function. If you call it from license page pre function, it changes the subtitles in all following pages.

thx for this help red wine and sorry but i have made search before posting with font and size font ( not " setfont " )and i don't have answers..... thx

You welcome :-)
I'd suggest first check for a certain resolution on target, then execute this code if needed, because on low resolutions wont look nice.

realy big thx ... it's work fine and i would ready to released my game for christmas... thx for u'r help