NSIS on HiDPI displays

Hello guys,

With the growth of HiDPI monitors, I'd like to have my NSIS installer compatible and running to its full potential.
As suggested by the documentation, I added

ManifestDPIAware true

to my script and it works well for most of the GUI.

However, I'm running into 2 issues:
- I provided welcome and header bitmaps at twice the recommended size, and it works on HiDPI displays. But on standard displays, the downsampling applied looks very cheap to me and I would prefer to provide separate bitmaps for each scale factor, is that possible?
- The checkboxes used in components page are not rescaled on HiDPI (they appear very small). Is there a way to use native Windows checkboxes instead of bitmaps?

Thanks for the help 🙂

For the checkboxes, I had a quick look at the code and the image list seems to be hardcoded to 16x16.

I guess if the scaled size of the treeview can be retrieved, then the check bitmap could be resized in memory and then applied to the treeview. This also depends on how old the OS is as to how well this would work.

I tried to create a "native" checkbox plug-in years ago but I never finished it because the theme API does not really support flat checkboxes IIRC.

It would be a nice addition to have flat checkboxes support. Looks like the only missing piece to a fully native-looking GUI.

Any ideas about welcome & header bitmaps? What's the proper way to have those bitmaps compatible with HiDPI diplays?

There are some stretch options for the bitmap IIRC but it is never going to look great. You could have images of multiple sizes and extract in .onInit I guess.

!include LogicLib.nsh
System::Call USER32::GetDpiForSystem()i.r0
${If} $0 U<= 0
    System::Call USER32::GetDC(i0)i.r1
    System::Call GDI32::GetDeviceCaps(ir1,i88)i.r0
    System::Call USER32::ReleaseDC(i0,ir1)
${EndIf}
MessageBox mb_ok SysDpi=$0 

and extract with a size based on https://msdn.microsoft.com/en-us/lib...px#CLOSEST_FIT

int iSourceImageDPIToUse = 96; // We will assume 96 by default.

if (gDPI > 144)
iSourceImageDPIToUse = 192;
else if (gDPI > 120)
iSourceImageDPIToUse = 144;
else if (gDPI > 96)
iSourceImageDPIToUse = 120;

Thanks! I will try that 🙂

I looked at what it takes to create this plug-in again and even before I get to the theme stuff I see that the classic DrawFrameControl function does not know how to draw read-only checkboxes so some post paint tweaking will be required.

If anybody interested, here is the piece of code I used to show different bitmaps according to the DPI setting

ManifestDPIAware true
!define MUI_PAGE_CUSTOMFUNCTION_SHOW showHiDpi
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "Resource\license.rtf"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!define MUI_PAGE_CUSTOMFUNCTION_SHOW showHiDpi
!insertmacro MUI_PAGE_FINISH
Function .onInit
    File /oname=$PLUGINSDIR\welcome96.bmp Resource\welcome96.bmp
    File /oname=$PLUGINSDIR\welcome120.bmp Resource\welcome120.bmp
    File /oname=$PLUGINSDIR\welcome144.bmp Resource\welcome144.bmp
    File /oname=$PLUGINSDIR\welcome192.bmp Resource\welcome192.bmp
    File /oname=$PLUGINSDIR\header96.bmp Resource\header96.bmp
    File /oname=$PLUGINSDIR\header120.bmp Resource\header120.bmp
    File /oname=$PLUGINSDIR\header144.bmp Resource\header144.bmp
    File /oname=$PLUGINSDIR\header192.bmp Resource\header192.bmp
FunctionEnd
Function showHiDpi
    System::Call USER32::GetDpiForSystem()i.r0 
    ${If} $0 U<= 0 
        System::Call USER32::GetDC(i0)i.r1 
        System::Call GDI32::GetDeviceCaps(ir1,i88)i.r0 
        System::Call USER32::ReleaseDC(i0,ir1) 
    ${EndIf} 
    ${Unless} $0 == 120
    ${AndUnless} $0 == 144
    ${AndUnless} $0 == 192
        StrCpy $0 96
    ${EndIf}
    ${NSD_SetImage} $mui.WelcomePage.Image $PLUGINSDIR\welcome$0.bmp $mui.WelcomePage.Image.Bitmap
    ${NSD_SetImage} $mui.FinishPage.Image $PLUGINSDIR\welcome$0.bmp $mui.FinishPage.Image.Bitmap
    SetBrandingImage /IMGID=1046 "$PLUGINSDIR\header$0.bmp"
FunctionEnd 

Also, it's important to note that HiDPI bitmaps size is not exactly the standard size multiplied by the scaling factor. Here are the values I used to fit perfectly (at least on Windows 10):

Header bitmap:
96dpi: 150x57
120dpi: 175x70
144dpi: 225x83
192dpi: 300x109

Welcome/Finish bitmap:
96dpi: 164x314
120dpi: 191x386
144dpi: 245x458
192dpi: 327x603

I would strongly recommend that you use the algorithm I posted, use >=, not == and pick the largest image you can fit.

Here is a very basic attempt to do native checkboxes, only classic style for now, will investigate themes later.

XPStyle on
ManifestDPIAware true

Page Components "" OnCompShow
Page InstFiles


Function OnCompShow
SysCompImg::ApplyFlat
FunctionEnd

Section Normal
SectionEnd
SectionGroup /e Group
Section /o UnChecked
SectionEnd
Section Checked
SectionEnd
SectionGroupEnd
Section /o RO:U
SectionIn RO
SectionEnd
Section RO:C
SectionIn RO
SectionEnd

Let me know how this looks

It looks good! Checkboxes scale correctly with the DPI.
Are they native Windows controls or custom drawing?

Originally Posted by Anders View Post

I would strongly recommend that you use the algorithm I posted, use >=, not == and pick the largest image you can fit.

Right, thanks 😉

It uses the DrawFrameControl API to draw on a custom imagelist. It is probably the same API used by the classic theme.

On the theme side of things, on Vista+ the TVS_EX_PARTIALCHECKBOXES style would be usable but TVS_EX_DIMMEDCHECKBOXES cannot be used for the read-only image so there is no way to get native flat themed checkboxes. Next step is to try to use the theme API to draw 3d checkboxes.

Thanks for investigating 🙂

I'm not familiar with neither Windows API nor NSIS internal programming, but wouldn't it make more sense to use native checkbox controls instead, like nsDialogs?

New version.

SetClassic: Classic flat look
SetFlat: Same as classic for now
SetThemed: Themed on XP+, same as SetFlat on <= 2000
GetSysDpi: System DPI in $0

Awesome! The checkboxes now really look consistent with the rest of the GUI

New version, added Unicode and 64-bit builds.

Support for custom bitmaps:

Function OnCompShow
SysCompImg::GetSysDpi
${If} $0 > 144
File "/oname=$PluginsDir\check.bmp" "${NSISDIR}\Contrib\Graphics\Checks\big.bmp" ; 192
${ElseIf} $0 > 120
File "/oname=$PluginsDir\check.bmp" "${NSISDIR}\Contrib\Graphics\Checks\red-round.bmp" ; 144
${ElseIf} $0 > 96
File "/oname=$PluginsDir\check.bmp" "${NSISDIR}\Contrib\Graphics\Checks\grey.bmp" ; 120
${Else}
File "/oname=$PluginsDir\check.bmp" "${NSISDIR}\Contrib\Graphics\Checks\simple.bmp" ; 96
${EndIf}
SysCompImg::SetCustom "$PluginsDir\check.bmp"
FunctionEnd

Really cool 🙂 Will this be merged into NSIS?

Yes, thanks for this, @Anders !

I've experimented with this a bit, and another issue is the scrollbars (for, e.g., the License Agreement) are very small.

Windows is drawing the scrollbars, not us. There is EnableNonClientDpiScaling but I don't think we can use it. I will investigate PerMonitorAwareV2, we might be able to support that.

I've tried using both a normal-size and an over-sized banner bmp (2x) using the modern_headerbmp.exe UI, but unlike mgrand I'm not seeing it scale properly at HiDPI (ie. at 200% I would have expected to work with the 2x sized banner). It appears to maintain the exact pixel counts regardless of scale or the image being used, instead of percentage coverage, as if the size was pixel-fixed (possibly in the modern_headerbmp.exe resource?). I used ResourceHacker to check the control sizes in the exe, but I couldn't determine which control affects the banner (a full-width banner, unlike 1046 which appears to be a 100x35 image).

ManifestDPIAware and ManifestSupportedOS have been set (true and all, respectively), which fixes the text scaling, but not the image. I've tried all the different settings with MUI_HEADERIMAGE_BITMAP_STRETCH to no avail. I've also attempted to use SetBrandingImage (as per https://stackoverflow.com/questions/...stallers-pages), along with using AddBrandingImage before calling SetBrandingImage to see if that changes the behaviour when using the oversized image, but I'm getting "no branding image found in chosen UI!" and I'm not sure that's the right way of solving this issue.

Any ideas?

Resources use dialog units, not pixels. The final pixel size is calculated by Windows at run-time and it is based on the font size (dialog unit) and DPI.

More information would be nice. Windows version? Is the primary monitor 200% DPI? Logged out and back in after changing DPI?

After some further investigation, it looks like we're manually setting image sizes via SetWindowPos(), which would explain the issues, so this has been resolved.

However, I noticed that the window size is slightly narrower in 120dpi mode (125%), while all other modes (100%, 150%, 200%) show the correct window width. This shows up because it will cut off part of the banner on the right side, as well as wrap text that doesn't wrap in any other dpi mode.

I'm also seeing something similar happening with jp/ko languages as well, regardless of DPI, but not to en-us or zh-cn. In the language case, the window is much wider than the normal window. I'm not sure it's necessarily related to the 125% mode issue, but it may be due to a similar mechanism.

Again, you are not telling me your Windows version.

The pixel size depends on the font because dialog units are based on the font. On Windows 10, some far east fonts are no longer installed by default and that might mess things up so make sure the font listed in the .nlf language file is actually installed. (Installing the keyboard layout and/or UI language should fix it IIRC)

For the 125% DPI problem, the Windows versions I have seen this on are Windows 7, 8.1, 10, and Server 2008 R2 non-exhaustive.

For the language issues, I've been testing with localized Windows 7 installations, but I believe I have seen them across a similar range at some point or another. So the takeaway here is to ensure that the font specified in the .nlf language files exist on the system first for localized installations...I will check on that, thanks.

The font issue only exists on Windows 10 (and 95/NT4 if you care about those).

I believe 120 dpi used to be known as Large Fonts in Windows and might have some weird compatibility hacks, not sure.

Sorry to revive an ancient thread, but I was struggling with getting the SysCompImg DLL to work, and hopefully this might help others. I'm using NSIS v3.06.1, MUI (and not MUI2, if it matters), and to get the DLL to work I had to call it using a custom function before the components page on dialog show via MUI_PAGE_CUSTOMFUNCTION_SHOW, eg:

!define MUI_PAGE_CUSTOMFUNCTION_SHOW ShowHiDpiComponents
!define MUI_PAGE_CUSTOMFUNCTION_PRE SetupComponents
!insertmacro MUI_PAGE_COMPONENTS

Function ShowHiDpiComponents
SysCompImg::SetThemed
FunctionEnd

Function SetupComponents
# Do my other pre-page code here
FunctionEnd

I'd been trying to call the DLL from the MUI_PAGE_CUSTOMFUNCTION_PRE function, and that just doesn't work.

I'd feel slightly happier if the source for SysCompImg was available somewhere too, but for now I'm happy to finally have HiDPI checkboxes in my installer!

MUI2

A problem exists in uninstallers.

SysCompImg.dll detects 144 dpi, if you set the DPI-aware declaration in ManifestDPIAware to 'true', correctly.

This is on a 4K monitor (with a 150% scale-factor for fonts and such).

It works for the installer but not for the uninstaller.

Maybe it's my mistake. I tried also "ManifestDPIAware true" in the uninstaller script, but the default (that can't be changed?) is false.

I can tell that Windows system does the scaling. And it should not.

The installer spawns the uninstaller. It looks hacky when the installer is 144 dpi 'not blurred' and the uninstaller is 96 dpi 'blurred'.

Note, I assume that 96 dpi is what happens when "ManifestDPIAware false" is set. Just I don't set it to that.

Originally Posted by rgreen View Post

It works for the installer but not for the uninstaller.

Maybe it's my mistake. I tried also "ManifestDPIAware true" in the uninstaller script, but the default (that can't be changed?) is false.

ManifestDPIAware is supposed to apply to both. What do you mean by "uninstaller script"?

Are you using !uninstfinalize to sign the uninstaller?

There might be some Windows caching going on if you previously had an older version without ManifestDPIAware?

You can download Resource Hacker (or Manifestview) and inspect the manifest of the uninstaller, it should have <dpiAware xmlns="...">true</dpiAware> in there somewhere.

It works correctly for me on Windows 10.